Panduan Dasar Menggunakan Fungsi LET di Excel dengan 10 Contoh Kasus

Fungsi LET di Excel memungkinkan Anda untuk mendefinisikan dan menyimpan nilai sementara dalam rumus, sehingga mempercepat proses perhitungan dan meningkatkan keterbacaan formula. Dengan LET, Anda dapat menghindari pengulangan referensi data yang sama dalam satu rumus, serta membuat formula lebih efisien.

Berikut ini adalah tutorial dasar penggunaan fungsi LET beserta 10 contoh kasus penggunaannya dengan tabel.

Sintaks Fungsi LET:

=LET(nama1; nilai1; [nama2; nilai2]; hasil_akhir)

Dimana:

• nama1 adalah nama variabel yang Anda definisikan.
• nilai1 adalah nilai yang akan dihubungkan dengan variabel nama1.
• nama2 dan seterusnya adalah nama variabel tambahan (opsional).
• hasil_akhir adalah hasil akhir yang dihitung berdasarkan variabel yang telah didefinisika

  Contoh 1: Perhitungan Sederhana

  Misalnya, Anda ingin menghitung penjumlahan dua angka, yaitu 10 dan 20.

  =LET(a; 10; b; 20; a + b)

  Hasil: 30                                                                                   

  Contoh 2: Penggunaan LET dalam Perhitungan Diskon

  Misalkan Anda menjual produk dengan harga Rp50.000 dan diskon 10%.

  =LET(harga; 50000; diskon; 0.1; harga - (harga * diskon))

  Hasil: 45000

Contoh 3: Menghitung Rata-rata dengan LET

Anda memiliki data penjualan seperti berikut:

Produk	Penjualan
Produk A	50
Produk B	60
Produk C	40

Rumus:

=LET(total; SUM(B2:B4); jumlah; COUNTA(B2:B4); total / jumlah)

Hasil: 50 (Rata-rata penjualan)                                                                                                                      

Contoh 4: Menghitung Pertumbuhan Penjualan

Anda memiliki data penjualan dari dua tahun berturut-turut:

Tahun	Penjualan
2023	100.000
2024	120.000

Rumus:

=LET(penjualan_awal; 100000; penjualan_akhir; 120000; (penjualan_akhir - penjualan_awal) / penjualan_awal)

Hasil: 0.2 (20% pertumbuhan)

Contoh 5: Menghitung Pajak Penghasilan

Misalkan Anda memiliki penghasilan Rp100.000.000 dan tarif pajak 15%.

=LET(penghasilan; 100000000; pajak; 0.15; penghasilan * pajak)

Hasil: 15000000

Contoh 6: Kombinasi LET dengan IF

Misalkan Anda ingin menghitung bonus penjualan, di mana penjualan lebih dari 100 unit mendapatkan bonus 10%, sedangkan penjualan kurang dari 100 unit mendapatkan bonus 5%.

Karyawan	Penjualan
A	110
B	90

Rumus:

=LET(penjualan; B2; bonus; IF(penjualan > 100; 0.1; 0.05); penjualan * bonus)

Untuk Karyawan A: 11 (Bonus 10%)

Contoh 7: Menghitung Laba Bersih

Anda memiliki data pendapatan dan biaya sebagai berikut:

Pendapatan	Biaya
500.000	300.000

Rumus:

=LET(pendapatan; 500000; biaya; 300000; pendapatan - biaya)

Hasil: 200000 (Laba bersih)

Contoh 8: Menghitung Luas Persegi Panjang

Misalkan Anda ingin menghitung luas persegi panjang dengan panjang 10 dan lebar 5.

=LET(panjang; 10; lebar; 5; panjang * lebar)

Hasil: 50

Contoh 9: Penggunaan LET untuk Perhitungan Persen Kenaikan

Anda memiliki data berikut:

Harga Awal	Harga Akhir
200.000	250.000

Rumus:

=LET(harga_awal; 200000; harga_akhir; 250000; (harga_akhir - harga_awal) / harga_awal * 100)

Hasil: 25% (kenaikan harga)

Contoh 10: Menggabungkan Nama dengan LET

Misalkan Anda memiliki data nama depan dan nama belakang seperti berikut:

Nama Depan	Nama Belakang
John	Doe

Rumus:

=LET(depan; A2; belakang; B2; depan & " " & belakang)

Hasil: John Doe

UNIQUE VALUES DENGAN RUMUS EXCEL 365

 

Selamat siang saya akan share lagi untuk menggunakan rumus untuk menghilangkan duplikat data, ada dua contoh yang saya berikan

CONTOH 1

Misalnya datanya seperti ini kemudian hasil yang diharapakan

Letakkan rumus di cell C2 di ENTER otomatis akan menghasilkan hasil seperti diatas

=UNIQUE(A2:A9)

CONTOH 2

pada contoh ke 2 ini kita akan menghilangkan duplikasi dan menghapus nama-nama yang tidak diinginkan

Kemudian list nama yang akan dihapus

Hasil yang diinginkan

Letakkan rumus ini di cell E2 kemudian Di ENTER otomatis akan menghasil hasil seperti diatas

=SORT(UNIQUE(FILTER(A2:A12;COUNTIF(C2:C4;A2:A12)=0))) 

Itu saja HAPPY LEARNING

Combine Multiple Columns in One Column (Excel 365 Formula)

 Saya ada artikel baru lagi nih geng, tentang bagaimana menggabungkan beberapa kolom menjadi satu kolom, seperti biasa contoh kolom data

Jadi ada 3 kolom yang akan kita gabungkan di dalam satu kolom seperti contoh di bawah

Rumusnya : 

=LET(Rngs;A1:A20;B1:B20;C1:C20);Rws;ROWS(INDEX(Rngs;;;1));Seq;SEQUENCE(AREAS(Rngs)*Rws;;0);Ary;INDEX(Rngs;MOD(Seq;Rws)+1;1;INT(Seq/Rws)+1);FILTER(Ary;Ary<>""))

Fungsi LAMBDA pada Excel 365 (BASIC)

Fungsi LAMBDA dalam Excel memungkinkan Anda untuk membuat fungsi kustom sendiri. Ini adalah fitur yang kuat yang memungkinkan Anda mendefinisikan dan menggunakan fungsi kustom dalam lembar kerja Excel Anda. Berikut penjelasan cara kerjanya:

SYNTAX:

=LAMBDA(parameter; perhitungan)

• parameter: Ini adalah daftar parameter yang dipisahkan koma yang akan diterima oleh fungsi kustom. Anda dapat memiliki hingga 253 parameter.

• perhitungan: Ini adalah perhitungan atau ekspresi yang menentukan apa yang dilakukan fungsi. Ini dapat merujuk pada parameter yang diberikan.

Contoh:

Misalkan Anda ingin membuat fungsi kustom bernama Tambah yang menambahkan dua angka.

=LAMBDA(a; b; a + b)

• a dan b adalah parameter.
• a + b adalah perhitungan.

Cara Menggunakan:

Cara mengsi rumus tersebut untuk membuat fungsi baru pada excel, klik pada tab FORMULA setelah itu "Define Name" untuk Name diisi "Tambah" kemudian rumus ini =LAMBDA(a; b; a + b) dimasukkan di "Refers to" kemudian klik OK. Setelah Anda mendefinisikan fungsi kustom Anda menggunakan LAMBDA, Anda dapat menggunakannya seperti fungsi Excel bawaan lainnya.

Misalnya, dengan fungsi kustom Tambah:

=Tambah(A1; A2)

Ini akan menambahkan nilai yang terdapat di sel A1 dan A2.

Jadi jika A1 berisi 2 dan A2 berisi 3, maka hasilnya akan menjadi 5.

Menghapus Beberapa Kata Menggunakan List Kriteria (Rumus Excel 365)

 Selamat pagi saya akan share beberapa problem solving menarik lagi dengan menggunakan rumus excel 365, dengan kasus menghapus beberapa kata menggunakan list kriteria, langsung saja
data

Data diatas beberapa kata akan dihapus menggunakan list kriteria pada kolom C jadi hasilnya seperti ini

Rumusnya, letakkan di cell H2 kemudian copas ke bawah:

=REDUCE(A2;C$2:C$4;LAMBDA(a;v;TRIM(SUBSTITUTE(a;v;""))))

atau

=LET(words;$C$2:$C$4; text; A2; REDUCE(text; words; LAMBDA(a;b; SUBSTITUTE(a; b; ""))))

Mungkin bisa mengahapus gelar seseorang? 

Fungsi FILTER (Microsoft Excel 365)

 Lama tak jumpa friends, pada kesempatan ini akan membahas penggunaan fungsi FILTER pada excel 365. Fungsi ini lebih canggih dari perpaduan INDEX dan MATCH atau VLOOKUP sekalipun

1. Satu Result dan Satu Kriteria

dan hasil yang diinginkan seperti ini

Pada cell D3 ketikkan rumus

=FILTER(B2:B4;A2:A4=D2;"")

2. Multiple Results dan Dengan Kriteria

Kemudian hasil yang diharapkan dengan kriterianya

Letakkan di cell D3
=FILTER(B2:B7;A2:A7=D2;"")

secara otomatis bisa menghasilkan beberapa hasil sesuai kriteria secara otomnatis tanpa copy satu per satu ke bawah.

3. Menampilkan Semua Kolom Sesuai Kriteria

Data seperti ini

Kemudian hasil yang diharapkan seperti ini

Letakkan rumus ini di cell H2 otomatis akan menghasilkan hasil spt diatas

=FILTER(A2:E11;B2:B11=H1)

4. Contoh lain dengan fungsi FILTER

Dengan menggunakan data sebelumnya tetapi hasil yang diinginkan berbeda jadi seperti ini

 

Ketikkan rumus di cell H4

=FILTER(B2:E11;(B2:B11=H1)+(B2:B11=H2))

Thnks guys

Menghilangkan Angka Nol dengan Custom Format

Kasusnya seperti ini ada beberapa angka nol yg ingin dihilangkan dengan custom format pada excel 

Langkahnya:

1. Blok dulu kolom yg warna kuning 

2. kemudian klik kanan lalu pilih Format Cells 

    

kemudian muncul menu Format Cells 

Pilih yang Custom

Kemudian input di bagian Type   0;-0;@ atau 0;-0;""

dan hasilnya

See u and take care guys

MENGHITUNG HURUF VOKAL DAN KONSONAN DALAM SEBUAH KATA

 Hello guys senang ketemu lagi kali kasusnya tidak berat2x amat ya menghitung jumlah huruf vokal dan konsonan dalam sebuah kata.

Kasus A (1 Kata)

Untuk menghitung vokal:

=SUMPRODUCT(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);{"a";"e";"i";"o";"u"};"")))

Untuk menghitung konsonan:

=LEN(A2)-SUMPRODUCT(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);{"a";"e";"i";"o";"u"};"" )))

Kasus B (Multiple Text)

Untuk menghitung vokal:

=SUMPRODUCT(LEN(SUBSTITUTE(A2;" ";""))-LEN(SUBSTITUTE(LOWER(SUBSTITUTE(A2;" ";""));{"a";"e";"i";"o";"u"};"")))

Untuk menghitung konsonan:

=LEN(SUBSTITUTE(A2;" ";""))-SUMPRODUCT(LEN(SUBSTITUTE(A2;" ";""))-LEN(SUBSTITUTE(LOWER(SUBSTITUTE(A2;" ";""));{"a";"e";"i";"o";"u"};"" )))

Sekian

Rizky B. Hendrawan

MENGHITUNG ANGKA DALAM SATU CELL

 Selamat pagi semuanya pada kesempatan kali ini saya share rumus untuk menghitung angka dalam satu cell, contoh kasusnya:

Jadi kasusnya menjumlahkan semua angka dalam satu cell

Rumusnya:

=SUM(IFERROR(MID(A1;ROW(INDIRECT("1:"&LEN(A1)));1)*1;0))

atau

=SUM(IFERROR(1*MID(A1;ROW($1:$99);1);))

ini rumus array ya jadi harus tekan tombol CTRL + SHIFT + ENTER bersamaan

take care guys

Cara Mengetahui Tahun Kabisat (Leap Year)

 Pagi readers jumpa lagi artikel baru lagi di tahun 2021 tentang bagaimana mengetahui bahwa sebuah tahun adalah tahun kabisat atau bukan.

Pengertian Tahun kabisat adalah tahun yang memiliki jumlah hari yang lebih banyak daripada tahun biasa dan terjadi tiap empat tahun sekali. Jika tahun biasa jumlah hari 365 maka pada tahun kabisat terdapat 366 hari dalam setahun.

Contoh kasus

Misalnya anda punya tahun di cell B1 dan aplikasi rumusnya ada beberapa contoh di bawah ini:

1. =IF(DATE(B1+1;1;1)-DATE(B1;1;1)=366;"Tahun Kabisat";"Bukan Tahun Kabisat")

2. =IF(DAY(EOMONTH(DATE(B1;2;1);0))=29;"Tahun Kabisat";"Bukan Tahun Kabisat")

3. =IF(((MOD(B1;4)=0)*((MOD(B1;100)<>0)+(MOD(B1;400)=0))=1);"Tahun Kabisat";"Bukan Tahun Kabisat")

Regards

Rizky

Memisahkan teks dan Angka

 Senang ketemu lagi tidak menulis artikel lagi di tahun 2020 dan 2021 karena sibuk pekerjaan, kesempatan ini saya akan memberi kasus tentang memisahkan teks dan angka, kasusnya dapat dilihat di bawah ini

Kasusnya seperti diatas, untuk rumusnya:

A. Untuk Mengambil Angka dari kasus diatas, letakan di cell E3 kemudian kopas kebawah:

1. =LOOKUP(9E+99+307;--MID(B3;MIN(FIND({1;2;3;4;5;6;7;8;9;0};B3&1234567890));ROW(INDIRECT("1:"&LEN(B3)))))         

 2. =LOOKUP(20^20;1*MID(B3;MIN(SEARCH({1;2;3;4;5;6;7;8;9;0};B3&1234567890));ROW(INDIRECT("1:"&LEN(B3)))))

B. Untuk Mengambil Teks dari kasus diatas, letakkan di cell D3 kemudian kopas ke bawah:

=TRIM(SUBSTITUTE($B3;$E3;""))

Selamat malam semua

Penjumlahan dan Menghitung Dengan OR Criteria

A. MENJUMLAHKAN MULTI KRITERIA
Assalamualaikum sudah lama sekali saya tidak memberikan artikel karena kesibukan pekerjaan mohon maafkan saya. Pada kesempatan yang baik di Bulan Ramadhan ini saya akan share pengetahuan saya dalam hal penjumlahan/menghitung dengan multi kriteria dalam satu kolom. Dulu masih belajar rumus excel saya cukup kesulitan dengan kasus ini silahkan lihat tabel kasusnya dibawah ini:

Kemudian kriterianya sebagai berikut, menjumlahkan semua sales dari 3 orang ini:

Dahulu saya pikir rumusnya seperti ini:
=SUMIFS(B2:B12;A2:A12;D2;A2:A12;D3;A2:A12;D4)

Dan apa hasilnya? Ya hasilnya akan "NOL", sebetulnya penggunaan fungsi SUMIFS memang cocok untuk multiple criteria tetapi tidak beberapa kriteria dalam satu kolom karena akan menghasilkan error.

Perhatikan gambar di bawah ini:

Cobalah blok bagian ini dan akan menghasilkan gambar di bawah ini setelah kita menekan tombol F9

Pada bagian yang saya beri nomor di bawah ini menggunakan 3 kriteria tetapi dalam 1 kolom

Dimana 2 kriteria atau lebih dilakukan pada kolom yang sama dan akan menghasilkan error.


Untuk mengatasinya perlu ada modifikasi rumus? Ada beberapa metode rumus:
1. =SUM(SUMIF(A2:A12;{"Joko";"Santi";"Dewi"};B2:B12))

2. =SUM(SUMIF(A2:A12;D2:D4;B2:B12)) --> Rumus array

3. =SUMIF(A2:A12;D2;B2:B12)+SUMIF(A2:A12;D3;B2:B12)+SUMIF(A2:A12;D4;B2:B12)


B. MENGHITUNG MULTI KRITERIA
Sama halnya dengan menghitung, langsung ke tkp

Dan kriterianya seperti ini

Tabel datanya sama ya dengan yang kasus menjumlahkan tadi bedanya yang ini hanya menghitung berapa penjualannya dari 3 orang tadi.
Kita tidak bisa menggunakan rumus seperti ini

Hasilnya akan nol.

Dapat diatasi dengan 3 metode rumus
1. =SUM(COUNTIF(A2:A12;{"Joko";"Santi";"Dewi"}))

2. =SUM(COUNTIFS(A2:A12;D2:D4)) --> Rumus Array

3. =COUNTIF(A2:A12;D2)+COUNTIF(A2:A12;D3)+COUNTIF(A2:A12;D4)

UNDUH FILE LATIHAN

Membuat Chart/Grafik Yang Menarik

Selamat pagi semuanya kawan-kawan semua, hari ini rasanya boring ya kalo membahas rumus saja, mungkin perlu saya selingi hal baru. Nah sesuai tema kali ini adalah memberikan contoh grafik atau chart yang menarik. Sementara saya belum kasih video tutorialnya, hanya file excel siap pakai dan gratis untuk digunakan dan mudah2xan dapat berguna untuk teman2x semua. Sebetulnya excel sendiri sudah menyediakan template grafik/chart ya tetapi bosan itu2x saja bentuknya maka dari itu kita tancap gas pol ke bawah.

1. Grafik Pertama (Progress Pie Chart)

2.  Grafik Kedua (Progress Pie Chart)

3. Grafik Ketiga (Baterry Chart)

4. Grafik Keempat (Tube Chart)

5. Grafik Kelima (Tube Chart)

6. Grafik Keenam (Half Progress Pie Chart)

7. Grafik Ketujuh (Male and Female Chart)

Silahkan download file latihan disini

Selamat Hari Raya Idul Fitri 1440H

Penjumlahan dan Menghitung Pada Cell Yang DIgabungkan (SUM IN MERGED CELLS)

Selamat menunaikan ibadah puasa ya bro dan sis, berbagi itu indah bukan, maka dari itu saya share kasus terbaru di bulan Ramadhan ini. Semoga menambah wawasan bro dan sis semuanya. Bagi pendatang baru silahkan bergabung.

Tabel Data

Dengan kriteria dan hasil yang diinginkan seperti ini:

Rumus untuk PENJUMLAHAN (Rumus Reguler):
=SUMPRODUCT((LOOKUP(ROW($A$2:$A$50);ROW($A$2:$A$50)/($A$2:$A$50<>"");$A$2:$A$50)=D3)*$B$2:$B$50)

Rumus untuk PENJUMLAHAN (Rumus Array):
=SUM((LOOKUP(ROW($A$2:$A$50);ROW($A$2:$A$50)/($A$2:$A$50<>"");$A$2:$A$50)=D3)*$B$2:$B$50)

Rumus untuk MENGHITUNG (Rumus Reguler):
=SUMPRODUCT((LOOKUP(ROW($A$2:$A$50);ROW($A$2:$A$50)/($A$2:$A$50<>"");$A$2:$A$50)=D13)*($B$2:$B$50<>""))

Rumus untuk MENGHITUNG (Rumus Array):
=SUM((LOOKUP(ROW($A$2:$A$50);ROW($A$2:$A$50)/($A$2:$A$50<>"");$A$2:$A$50)=D13)*($B$2:$B$50<>""))

FILE DOWNLOAD

Membuat QR Code dan Barcode

Artikel kali ini akan membahas pembuatan QR Code dan Barcode, sebelum kita memulai dengan rumus dan makronya kita pahami dulu arti dan fungsi dari barcode dan qr code. Fungsi Barcode adalah sebagai sarana untuk mempermudah kita dalam menginput data dimana cara kerjanya input data otomatis dengan membaca kode. Barcode adalah kode batang dengan garis hitam hitam diatas background putih. Sedangkan Kode QR atau biasa dikenal dengan istilah QR (Quick Response) Code adalah bentuk evolusi kode batang dari satu dimensi menjadi dua dimensi. Penggunaan kode QR sudah sangat lazim di Jepang Hal ini dikarenakan kemampuannya menyimpan data yang lebih besar dari pada kode batang sehingga mampu mengkodekan informasi dalam bahasa Jepang sebab dapat menampung huruf kanji. Kode QR telah mendapatkan standarisasi internasional dan standarisasi dari Jepang berupa ISO/IEC18004 dan JIS-X-0510 dan telah digunakan secara luas melalui ponsel di Jepang.

Mari kita mulai penjelasannya, tetapi sebelum itu anda harus mengaktifkan makro anda dulu, biasanya fasilitas makro ini tidak diaktifkan oleh antivirus, mari kita ikuti langkah2xnya dibawah ini:
1. Bukalah excel anda kemudian klik Menu File, kemudian klik menu teks "Options":

2. Kemudian klik menu "Trust Center":

3. Kemudian akan muncul tombol yang bertuliskan "Trust Center Setting", di klik saja

4. Akan muncul menu seperti ini, silahkan klik pada "Macro Settings" (lihat gambar)

5. Klik pada sebelah kanan "Enable All Macros"

Setelah selesai sesuai alur diatas silahkan tutup excel anda.

KASUS 1: QR CODE

Nah diatas adalah tampilan dari QR Code, ini menggunakan makro karena sifatnya yang 2 dimensional dan syaratnya anda harus online karena kode makro ini memakai Google Chart API. Kode Makronya:

Function Insert_QR(codetext As String)
Dim URL As String, MyCell As Range

Set MyCell = Application.Caller
URL = "https://chart.googleapis.com/chart?chs=125x125&cht=qr&chl=" & codetext
On Error Resume Next
  ActiveSheet.Pictures("My_QR_" & MyCell.Address(False, False)).Delete 'delete if there is prevoius one
On Error GoTo 0
ActiveSheet.Pictures.Insert(URL).Select
With Selection.ShapeRange(1)
 .PictureFormat.CropLeft = 15
 .PictureFormat.CropRight = 15
 .PictureFormat.CropTop = 15
 .PictureFormat.CropBottom = 15
 .Name = "My_QR_" & MyCell.Address(False, False)
 .Left = MyCell.Left + 25
 .Top = MyCell.Top + 5
End With
Insert_QR = "" ' or some text to be displayed behind code
End Function

Makro ini membuat UDF atau "User Defined Function" atau semacam membuat fungsi baru pada excel, dengan sintaks sebagai berikut:

=Insert_QR(C4)

Fungsi ini akan memunculkan kode QR secara otomatis dan rumus ini dapat kita letakkan di bawah kode QR. Untuk mengaplikasikan kode makro ini, silahkan buat modul baru di halaman VBA dengan menekan tombol ALT+F11 tekan secara bersamaan. Jika sudah silahkan lihat gambar di bawah ini untuk pengetikan rumusnya.

Setelah mengetikkan rumus seperti di gambar tekanlah tombol ENTER, kemudian akan muncul QR code:

Setelah itu simpan file excel anda sebagai makro dengan ektensi XLSM, jangan sampai salah di simpan sebagai XLSX karena makro tidak akan jalan dan kode QR tidak akan tampil.

KASUS 2: BARCODE

Tampak diatas ada 2 macam bentuk barcode yaitu code 39 (yang atas) dan code 128 (bawah). Apa perbedaannya? Perbedaan utama antara Kode 39 dan Kode 128, seperti yang dapat Anda lihat dari contoh gambar di atas adalah bahwa Kode 128 memiliki kepadatan data yang jauh lebih tinggi daripada Kode 39. Oleh karena itu, kami menyarankan Anda memberi label barang sangat kecil menggunakan kode 128 barcode. Dan penerapan pada excel anda hanya butuh font atau jenis huruf barcode yang bisa anda download di artikel ini, dan ini merupakan jenis font barcode yang gratis ya karena ada juga yang lebih premium. Pertama anda harus menginstall nya dulu ke sistem windows supaya font barcode tersebut dapat digunakan di excel.

Cara Install Font Barcode
1. Anda download dulu disini font-nya KODE BARCODE 39 dan KODE BARCODE 128
2. Kemudian anda klik kanan dengan mouse anda kemudian akan muncul menu seperti ini

Kemudian klik pada "INSTALL", kemudian proses akan berjalan otomatis

Pada gambar diatas saya baru saja menginstall font barcode 39 dan lakukan hal yang sama dengan font barcode 128. Kemudian kita lanjutkan untuk mengaplikasikannya pada excel.
Langkahnya:
1. Bukalah excel anda
2. Ketiklah kalimat atau angka terserah anda di cell A2

3. Kemudian cari font atau jenis huruf dengan nama"Free 3 of 9 Extended"

Kemudian tekan ENTER setelah anda pilih font tersebut.
4. Setelah itu ketiklah rumus ini pada cell B2:
="*"&A2&"*"
Kenapa seperti itu? Karena kode 39 adalah simbologi yang paling populer di dunia non-ritel dan digunakan secara luas di bidang manufaktur, militer, dan aplikasi kesehatan. Setiap kode Kode 39 bar dibingkai oleh karakter start / stop diwakili oleh tanda bintang (*). Asterisk dicadangkan untuk tujuan ini dan tidak boleh digunakan di badan pesan.
5. Aplikasi untuk barcode 128

Untuk kode 128 rumusnya hanya cell referensi saja, letakkan di cell B5 =A5 setelah itu pilihlah jenis fontnya
Mudah2xan jelas yah, dan semoga artikel ini berguna untuk dapat memahami seputar qr code dan barcode.
FILE LATIHAN DOWNLOAD