22 Januari 2014

Mempersingkat Nama Depan, Tengah dan Nama Belakang

Ass.Wr.Wb.

Selamat siang para pembaca, hari ini saya akan posting rumus untuk memodifikasi teks, kebetulan ada kasus mempersingkat nama. Nah biasanya yang lazim yang disingkat adalah nama depan, nama tengah, tapi nama belakang disingkat juga lazim sih....

Joko Santoso Mulyono disingkat menjadiJ. Santoso Mulyono atau Joko S. Mulyono atau Joko Santoso M.


Solusi Mempersingkat Nama Depan:

=LEFT(A1;1)&". "&MID(A1;FIND(" ";A1)+1;255)

atau

=REPLACE(A1;2;FIND(" ";A1)-2;".")

Solusi Mempersingkat Nama Tengah:

=REPLACE(A1;FIND(" ";A1)+2;FIND(" ";A1;FIND(" ";A1)+1)-FIND(" ";A1)-2;".")

atau

=CHOOSE(LEN(A1)-LEN(SUBSTITUTE(A1;" ";""));A1;SUBSTITUTE(A1;MID(A1;SEARCH(" ";A1)+1;SEARCH(" ";A1;SEARCH(" ";A1)+1)-SEARCH(" ";A1));MID(A1;SEARCH(" ";A1)+1;1)&". "))


Solusi Mempersingkat Nama Belakang:

=TRIM(LEFT(A1;SEARCH(" ";A1;SEARCH(" ";A1;1)+1)))&" "&MID(A1;FIND(" ";A1;FIND(" ";A1;1)+1)+1;1)&"."

atau

=LEFT(TRIM(A1);FIND("~";SUBSTITUTE(A1;" ";"~";LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(A1);" ";""))))-1)&" "&MID(A1;FIND("~";SUBSTITUTE(A1;" ";"~";LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))))+1;1)&"."

 Solusi Mempersingkat 2 Nama Depan:

=LEFT(A1;1)&"."&(MID(A1;FIND(" ";A1;1)+1;1))&". "&TRIM(RIGHT(SUBSTITUTE(A1;" ";REPT(" ";256));256))


Solusi Membuat Inisial:

Misalkan dari contoh nama diatas kita ingin membuat inisialnya, dari Joko Santosa Mulyono menjadi JSM, nah rumusnya.....

=IFERROR(LEFT(A1;1)&(MID(A1;FIND(" ";A1;1)+1;1))&MID(A1;FIND(" ";A1;FIND(" ";A1)+1)+1;1);LEFT(A1;1)&(MID(A1;FIND(" ";A1;1)+1;1)))

atau

=IF(LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))=0;LEFT(A1;1);IF(LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))=1;LEFT(A1;1)&MID(A1;FIND(" ";A1)+1;1);LEFT(A1;1)&MID(A1;FIND(" ";A1)+1;1)&MID(A1;FIND(" ";A1;FIND(" ";A1)+1)+1;1)))

Dicoba ya.....matursuwun

Rizky

Download File Latihan

26 komentar:

  1. Keren masss blog nyaaa... Bermanfaat banget... Thanks yaa

    BalasHapus
  2. kalo cara merubah inisial jadi nama gimana
    contohnya.. L Jadi laki-laki P jadi Perempuan

    BalasHapus
    Balasan
    1. Pake IF saja mas, misalnya anda punya huruf "L" atau "P" di cell A1, =IF(A1="L";"Laki-laki";IF(A1="P";"Perempuan";""))

      Hapus
  3. bagaimana cara membuat kunci nama sebagai contoh Ariyanti di cell A1, kemudian tidak perlu mengetik lagi nama Ariyanti tapi cukup dengan ketik A1 akan muncul nama Ariyanti

    BalasHapus
  4. Jika anda mempunyai teks di A1 "Ariyati", letakkan rumus ini di cell lain

    =INDIRECT(ADDRESS(1;1))

    BalasHapus
  5. ACR -BOX TESTER // 38 X 32 X 11
    APEX -H 2872 / 1051 // POWER FLOW

    KALAU MAU AMBIL INI AJA BAGAIMANA?
    BOX TESTER
    H 2872 / 1051

    BalasHapus
    Balasan
    1. =LEFT(MID(A1;FIND("-";A1)+1;FIND(CHAR(1);SUBSTITUTE(A1;" ";CHAR(1);LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))))-(FIND(" ";A1)+1));LOOKUP(2^15;FIND(" // ";" "&MID(A1;FIND("-";A1)+1;FIND(CHAR(1);SUBSTITUTE(A1;" ";CHAR(1);LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))))-(FIND(" ";A1)+1));ROW(INDIRECT("1:"&LEN(MID(A1;FIND("-";A1)+1;FIND(CHAR(1);SUBSTITUTE(A1;" ";CHAR(1);LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))))-(FIND(" ";A1)+1)))))))-1)

      Hapus
  6. Kalo buat kayak di daftar pustaka gimna ya. Misal abid amri jadi amri.A

    BalasHapus
    Balasan
    1. Bisa, hanya saja apakah kasusnya hanya nama dengan 2 kata? Bagaimana dengan 3 kata, 4 kata dan seterusnya. Jika punya kasus lengkapnya dengan disertai contoh hasil yang ingin ditampilkan dapat di email ke saya rizky_bh@ugm.ac.id atau rizkybhendrawan@gmail.com, mudah2xan saya bisa bantu

      Hapus
    2. makasih bang tugas sekolah saya sudh brs

      Hapus
  7. Mas, minta tulung untuk kasus nama hanya satu kata dan 2 kata saja, contoh Yusup jadi YSP DAN Yusup Ridwan jadi YRN, adakah

    BalasHapus
    Balasan
    1. Mungkin begini pak, silahkan copas rumus ini di B1 semisal data nama anda dimulai dari cell A1 kebawah

      =IF(LEN(A1)-LEN(SUBSTITUTE(A1;" ";""))=0;UPPER(LEFT(A1;1))&UPPER(MID(A1;3;1))&UPPER(RIGHT(A1;1));IFERROR(LEFT(A1;1)&(MID(A1;FIND(" ";A1;1)+1;1))&MID(A1;FIND(" ";A1;FIND(" ";A1)+1)+1;1);LEFT(A1;1)&(MID(A1;FIND(" ";A1;1)+1;1)))&UPPER(RIGHT(A1;1)))

      Hapus
  8. mohon bantu suhu Rizky, jika nama Joko Santoso diubah menjadi Joko S
    ( kata pertama + huruf pertama kata kedua)

    BalasHapus
    Balasan
    1. =LEFT(A1;FIND(" ";A1;1)-1)&" "&IF(LEFT(TRIM(SUBSTITUTE(A1;LEFT(A1;FIND(" ";A1;1)-1);""));1)<>"";LEFT(TRIM(SUBSTITUTE(A1;LEFT(A1;FIND(" ";A1;1)-1);""));1)&".";"")

      Hapus
  9. Bagaimana jika nama perusahaan misal PT Angin Ribut Sekali agar menjadi PT ARS

    BalasHapus
    Balasan
    1. sama dengan saya mas kebutuhannya, saya pakai rumus diatas, kebetulan nama PT ada 4 kata, cuma yang muncul inisal cuma 3 huruf. apa ada rumusnya? terimakasih sebelumnya

      Hapus
  10. ass..
    mas, kalo ambil nama di file lain, kemudian di tambah 1 / 2 / 3 dst, cara nya gimana...?

    BalasHapus
    Balasan
    1. Jika ada pertanyaan silahkan kirim email saya ke saya beserta file excelnya ke rizkybhendrawan@gmail.com

      Hapus
  11. SAYA PAKE EXCEL 2013. DAN NYOBA PAAKE RUMUS IF

    =IF(U7,("BD","BANDUNG"),("JK","JAKARTA"),("SY","SURABAYA"),("MD","MEDAN"))))

    KO EROR TERUS YA PAK

    BalasHapus
    Balasan
    1. Apakah referensi cell di U7 atau bukan, karena rumus menunjukkan referensi cell ke U7

      Hapus
  12. kalau mempersingkat nama Dessy Indah Wulan Sari
    menjadi Dessy I P W S gimana ya kak

    BalasHapus