Summing and Counting with Multiple Criteria

Bagi anda pengguna Excel 2007 dan 2010 pasti tidak asing dengan Fungsi SUMIFS() dan COUNTIFS(), yaitu fungsi yang dapat digunakan untuk menjumlahkan dan menghitung data dengan 2 atau lebih kriteria. Tetapi kali ini saya tidak membahas keduanya. Saya akan memberikan contoh yang dapat digunakan pada Excel Versi 2003 dan versi diatasnya untuk menjumlahkan dan menghitung data dengan multiple criteria.

Dengan Contoh Kasus Tabel Data diatas, kita ingin memecahkan beberapa Kasus :

1. Menghitung penjualan pada bulan Februari
    =SUMIF(C2:C11;"Februari";E2:E11) --> 1126

2. Berapa kali penjualan yang terjadi pada Bulan Februari ?
    =COUNTIF(C2:C11;"Februari") --> 4

3. Menghitung penjualan pada bulan SELAIN bulan Februari
    =SUMIF(C2:C11;"<>Februari";E2:E11) --> 2968

4. Menghitung penjualan pada bulan Februari dan bulan April
    =SUMIF(C2:C11;"Februari";E2:E11)+SUMIF(C2:C11;"April";E2:E11) --> 2193

5. Menghitung penjualan pada bulan Februari dan dijual oleh Garin
    =SUM((B2:B10="Garin")*(C2:C10="Februari")*E2:E10) --> 550
    Karena perhitungan ini menggunakan 2 kriteria maka Fungsi SUMIF() tidak bisa digunakan, dan jangan
    lupa untuk menekan Ctrl+Shift+Enter karena ini rumus Array.

6. Menghitung penjualan yang dilakukan oleh Salesman selain "Kurnia" pada Bulan April
    =SUM((B2:B11<>"Kurnia")*(C2:C11="April")*E2:E11) --> 811
    (Rumus Array)

7. Berapa kali penjualan yang dilakukan oleh Garin pada Bulan Februari ?
    =SUM(IF(B2:B11="Garin";IF(C2:C11="Februari";1;0);0))
    (Rumus Array)
    atau
    =SUM((B2:B11="Garin")*(C2:C11="Februari")) --> 2
    (Rumus Array)

8. Berapa kali penjualan yang dilakukan selama Bulan Agustus yang laku >=500 pcs ?
    =SUM((C2:C11="Agustus")*(E2:E11>=500)) --> 3
    (Rumus Array)

9. Berapa pcs barang yang laku dijual dengan Range >=300 pcs dan <=700 pcs
    =SUM((E2:E11>=300)*(E2:E11<=700)*(E2:E11)) --> 2500
   (Rumus Array)

10.  Berapa kali penjualan barang yang terjadi dengan Range >=300 pcs dan <=700 pcs ?
    =SUM((E2:E11>=300)*(E2:E11<=700)) --> 5
    (Rumus Array)

Silahkan berkreasi dengan contoh rumus-rumus diatas dengan contoh tabel diatas atau memakai data anda sendiri.