RUMUS TERBILANG

 Saya hari ini iseng-iseng membuat rumus terbilang, yaitu mengkonversi angka menjadi kata misalnya 1000 menjadi Seribu Rupiah

KASUSNYA SEPERTI INI

Bikinnya seperti ini

1. Buat Name pada menu Formula dengan klik pada "Define Name" kemudian letakkan rumus ini pada "REFERS TO" 

=LAMBDA(n; LET( angka;{"";"Satu";"Dua";"Tiga";"Empat";"Lima";"Enam";"Tujuh";"Delapan";"Sembilan";"Sepuluh";"Sebelas"}; hasil; IF(n<12;INDEX(angka;n+1); IF(n<20;TERBILANG(n-10)&" Belas"; IF(n<100;TERBILANG(INT(n/10))&" Puluh "&TERBILANG(MOD(n;10)); IF(n<200;"Seratus "&TERBILANG(n-100); IF(n<1000;TERBILANG(INT(n/100))&" Ratus "&TERBILANG(MOD(n;100)); IF(n<2000;"Seribu "&TERBILANG(n-1000); IF(n<1000000;TERBILANG(INT(n/1000))&" Ribu "&TERBILANG(MOD(n;1000)); IF(n<1000000000;TERBILANG(INT(n/1000000))&" Juta "&TERBILANG(MOD(n;1000000)); IF(n<1000000000000;TERBILANG(INT(n/1000000000))&" Miliar "&TERBILANG(MOD(n;1000000000)); TERBILANG(INT(n/1000000000000))&" Triliun "&TERBILANG(MOD(n;1000000000000)) ))))))))); TRIM(hasil) ))

Kemudian klik "OK"

kemudian ketik pada cell A4 =TERBILANG(A2)

Ok gitu saja

Terimakasih

 Berikut ini adalah 10 kasus penggunaan fungsi LET di Excel dengan level menengah, dilengkapi dengan tabel untuk masing-masing kasus. Fungsi LET memungkinkan kita mendefinisikan variabel dalam satu formula, sehingga membantu dalam mengurangi kompleksitas perhitungan.

---

1. Menghitung Total Harga Setelah Diskon Berdasarkan Kategori Produk

Produk	Kategori	Harga	Diskon (%)
Produk A	A	100	10
Produk B	B	200	15
Produk C	A	150	5
Produk D	C	250	20

Formula untuk menghitung total harga setelah diskon:

=LET(Harga; B2; Diskon; C2; Harga_Akhir; Harga * (1 - Diskon / 100); Harga_Akhir)

---

2. Menghitung Rata-Rata Nilai Siswa Berdasarkan Mata Pelajaran

Nama	Matematika	Fisika	Kimia
Siswa A	80	85	90
Siswa B	70	75	80
Siswa C	90	95	85

Formula untuk menghitung rata-rata nilai:

LET(Nilai1; B2; Nilai2; C2; Nilai3; D2; RataRata; (Nilai1 + Nilai2 + Nilai3) / 3; RataRata)

---

3. Menghitung Komisi Penjualan Berdasarkan Persentase Penjualan

Sales	Penjualan	Persentase Komisi (%)
Sales A	1000	5
Sales B	2000	10
Sales C	3000	7.5

Formula untuk menghitung komisi:

excel

=LET(Penjualan; B2; Komisi; C2; TotalKomisi; Penjualan * (Komisi / 100); TotalKomisi)

---

4. Mengonversi Nilai Suhu dari Fahrenheit ke Celsius

Kota	Suhu (Fahrenheit)
New York	98.6
Tokyo	104
London	95

Formula untuk konversi suhu:

excel

=LET(SuhuF; B2; SuhuC; (SuhuF - 32) * 5 / 9; SuhuC)

---

5. Menghitung Sisa Hasil Pembagian dengan Variabel Didefinisikan

Angka A	Angka B
25	4
50	6
37	5

Formula untuk menghitung sisa pembagian:

excel
=LET(A; B2; B; C2; Sisa; MOD(A; B); Sisa)

---

6. Menghitung Biaya Layanan dengan Pajak dan Diskon

Layanan	Biaya	Pajak (%)	Diskon (%)
Layanan A	500	10	5
Layanan B	800	8	10
Layanan C	400	12	7

Formula untuk menghitung biaya setelah pajak dan diskon:

excel

=LET(Biaya; B2; Pajak; C2; Diskon; D2; TotalBiaya; Biaya * (1 + Pajak / 100) * (1 - Diskon / 100); TotalBiaya)

---

7. Menghitung Sisa Persediaan Barang Setelah Penjualan

Barang	Persediaan	Terjual
Barang A	100	20
Barang B	200	50
Barang C	150	30

Formula untuk menghitung sisa persediaan:

excel

=LET(Stock; B2; Sold; C2; Remaining; Stock - Sold; Remaining)

---

8. Menghitung Harga Pokok Penjualan Berdasarkan Biaya Produksi

Produk	Biaya Bahan	Biaya Tenaga Kerja	Biaya Lainnya
Produk X	500	200	100
Produk Y	700	250	150

Formula untuk menghitung harga pokok penjualan:

=LET(Bahan; B2; TenagaKerja; C2; BiayaLain; D2; HPP; Bahan + TenagaKerja + BiayaLain; HPP)

---

9. Menghitung Tingkat Persentase Pencapaian Target

Nama	Target Penjualan	Realisasi Penjualan
Agen A	1000	900
Agen B	1500	1400
Agen C	1200	1100

Formula untuk menghitung persentase pencapaian:

=LET(Target; B2; Realisasi; C2; PersenPencapaian; Realisasi / Target * 100; PersenPencapaian)

---

10. Menghitung Volume Prisma Segitiga

Prisma	Panjang	Lebar	Tinggi
Prisma A	5	10	8
Prisma B	6	9	7

Formula untuk menghitung volume prisma segitiga:

=LET(Panjang; B2; Lebar; C2; Tinggi; D2; Volume; 0.5 * Panjang * Lebar * Tinggi; Volume)

---

Dengan menggunakan fungsi LET pada kasus-kasus di atas, perhitungan menjadi lebih terstruktur dan mudah dibaca, karena variabel di dalam formula memberikan penamaan yang jelas.

Panduan Dasar Menggunakan Fungsi LET di Excel dengan 10 Contoh Kasus

Fungsi LET di Excel memungkinkan Anda untuk mendefinisikan dan menyimpan nilai sementara dalam rumus, sehingga mempercepat proses perhitungan dan meningkatkan keterbacaan formula. Dengan LET, Anda dapat menghindari pengulangan referensi data yang sama dalam satu rumus, serta membuat formula lebih efisien.

Berikut ini adalah tutorial dasar penggunaan fungsi LET beserta 10 contoh kasus penggunaannya dengan tabel.

Sintaks Fungsi LET:

=LET(nama1; nilai1; [nama2; nilai2]; hasil_akhir)

Dimana:

• nama1 adalah nama variabel yang Anda definisikan.
• nilai1 adalah nilai yang akan dihubungkan dengan variabel nama1.
• nama2 dan seterusnya adalah nama variabel tambahan (opsional).
• hasil_akhir adalah hasil akhir yang dihitung berdasarkan variabel yang telah didefinisika

  Contoh 1: Perhitungan Sederhana

  Misalnya, Anda ingin menghitung penjumlahan dua angka, yaitu 10 dan 20.

  =LET(a; 10; b; 20; a + b)

  Hasil: 30                                                                                   

  Contoh 2: Penggunaan LET dalam Perhitungan Diskon

  Misalkan Anda menjual produk dengan harga Rp50.000 dan diskon 10%.

  =LET(harga; 50000; diskon; 0.1; harga - (harga * diskon))

  Hasil: 45000

Contoh 3: Menghitung Rata-rata dengan LET

Anda memiliki data penjualan seperti berikut:

Produk	Penjualan
Produk A	50
Produk B	60
Produk C	40

Rumus:

=LET(total; SUM(B2:B4); jumlah; COUNTA(B2:B4); total / jumlah)

Hasil: 50 (Rata-rata penjualan)                                                                                                                      

Contoh 4: Menghitung Pertumbuhan Penjualan

Anda memiliki data penjualan dari dua tahun berturut-turut:

Tahun	Penjualan
2023	100.000
2024	120.000

Rumus:

=LET(penjualan_awal; 100000; penjualan_akhir; 120000; (penjualan_akhir - penjualan_awal) / penjualan_awal)

Hasil: 0.2 (20% pertumbuhan)

Contoh 5: Menghitung Pajak Penghasilan

Misalkan Anda memiliki penghasilan Rp100.000.000 dan tarif pajak 15%.

=LET(penghasilan; 100000000; pajak; 0.15; penghasilan * pajak)

Hasil: 15000000

Contoh 6: Kombinasi LET dengan IF

Misalkan Anda ingin menghitung bonus penjualan, di mana penjualan lebih dari 100 unit mendapatkan bonus 10%, sedangkan penjualan kurang dari 100 unit mendapatkan bonus 5%.

Karyawan	Penjualan
A	110
B	90

Rumus:

=LET(penjualan; B2; bonus; IF(penjualan > 100; 0.1; 0.05); penjualan * bonus)

Untuk Karyawan A: 11 (Bonus 10%)

Contoh 7: Menghitung Laba Bersih

Anda memiliki data pendapatan dan biaya sebagai berikut:

Pendapatan	Biaya
500.000	300.000

Rumus:

=LET(pendapatan; 500000; biaya; 300000; pendapatan - biaya)

Hasil: 200000 (Laba bersih)

Contoh 8: Menghitung Luas Persegi Panjang

Misalkan Anda ingin menghitung luas persegi panjang dengan panjang 10 dan lebar 5.

=LET(panjang; 10; lebar; 5; panjang * lebar)

Hasil: 50

Contoh 9: Penggunaan LET untuk Perhitungan Persen Kenaikan

Anda memiliki data berikut:

Harga Awal	Harga Akhir
200.000	250.000

Rumus:

=LET(harga_awal; 200000; harga_akhir; 250000; (harga_akhir - harga_awal) / harga_awal * 100)

Hasil: 25% (kenaikan harga)

Contoh 10: Menggabungkan Nama dengan LET

Misalkan Anda memiliki data nama depan dan nama belakang seperti berikut:

Nama Depan	Nama Belakang
John	Doe

Rumus:

=LET(depan; A2; belakang; B2; depan & " " & belakang)

Hasil: John Doe

UNIQUE VALUES DENGAN RUMUS EXCEL 365

 

Selamat siang saya akan share lagi untuk menggunakan rumus untuk menghilangkan duplikat data, ada dua contoh yang saya berikan

CONTOH 1

Misalnya datanya seperti ini kemudian hasil yang diharapakan

Letakkan rumus di cell C2 di ENTER otomatis akan menghasilkan hasil seperti diatas

=UNIQUE(A2:A9)

CONTOH 2

pada contoh ke 2 ini kita akan menghilangkan duplikasi dan menghapus nama-nama yang tidak diinginkan

Kemudian list nama yang akan dihapus

Hasil yang diinginkan

Letakkan rumus ini di cell E2 kemudian Di ENTER otomatis akan menghasil hasil seperti diatas

=SORT(UNIQUE(FILTER(A2:A12;COUNTIF(C2:C4;A2:A12)=0))) 

Itu saja HAPPY LEARNING

Combine Multiple Columns in One Column (Excel 365 Formula)

 Saya ada artikel baru lagi nih geng, tentang bagaimana menggabungkan beberapa kolom menjadi satu kolom, seperti biasa contoh kolom data

Jadi ada 3 kolom yang akan kita gabungkan di dalam satu kolom seperti contoh di bawah

Rumusnya : 

=LET(Rngs;A1:A20;B1:B20;C1:C20);Rws;ROWS(INDEX(Rngs;;;1));Seq;SEQUENCE(AREAS(Rngs)*Rws;;0);Ary;INDEX(Rngs;MOD(Seq;Rws)+1;1;INT(Seq/Rws)+1);FILTER(Ary;Ary<>""))

Fungsi LAMBDA pada Excel 365 (BASIC)

Fungsi LAMBDA dalam Excel memungkinkan Anda untuk membuat fungsi kustom sendiri. Ini adalah fitur yang kuat yang memungkinkan Anda mendefinisikan dan menggunakan fungsi kustom dalam lembar kerja Excel Anda. Berikut penjelasan cara kerjanya:

SYNTAX:

=LAMBDA(parameter; perhitungan)

• parameter: Ini adalah daftar parameter yang dipisahkan koma yang akan diterima oleh fungsi kustom. Anda dapat memiliki hingga 253 parameter.

• perhitungan: Ini adalah perhitungan atau ekspresi yang menentukan apa yang dilakukan fungsi. Ini dapat merujuk pada parameter yang diberikan.

Contoh:

Misalkan Anda ingin membuat fungsi kustom bernama Tambah yang menambahkan dua angka.

=LAMBDA(a; b; a + b)

• a dan b adalah parameter.
• a + b adalah perhitungan.

Cara Menggunakan:

Cara mengsi rumus tersebut untuk membuat fungsi baru pada excel, klik pada tab FORMULA setelah itu "Define Name" untuk Name diisi "Tambah" kemudian rumus ini =LAMBDA(a; b; a + b) dimasukkan di "Refers to" kemudian klik OK. Setelah Anda mendefinisikan fungsi kustom Anda menggunakan LAMBDA, Anda dapat menggunakannya seperti fungsi Excel bawaan lainnya.

Misalnya, dengan fungsi kustom Tambah:

=Tambah(A1; A2)

Ini akan menambahkan nilai yang terdapat di sel A1 dan A2.

Jadi jika A1 berisi 2 dan A2 berisi 3, maka hasilnya akan menjadi 5.

Menghapus Beberapa Kata Menggunakan List Kriteria (Rumus Excel 365)

 Selamat pagi saya akan share beberapa problem solving menarik lagi dengan menggunakan rumus excel 365, dengan kasus menghapus beberapa kata menggunakan list kriteria, langsung saja
data

Data diatas beberapa kata akan dihapus menggunakan list kriteria pada kolom C jadi hasilnya seperti ini

Rumusnya, letakkan di cell H2 kemudian copas ke bawah:

=REDUCE(A2;C$2:C$4;LAMBDA(a;v;TRIM(SUBSTITUTE(a;v;""))))

atau

=LET(words;$C$2:$C$4; text; A2; REDUCE(text; words; LAMBDA(a;b; SUBSTITUTE(a; b; ""))))

Mungkin bisa mengahapus gelar seseorang? 

Fungsi FILTER (Microsoft Excel 365)

 Lama tak jumpa friends, pada kesempatan ini akan membahas penggunaan fungsi FILTER pada excel 365. Fungsi ini lebih canggih dari perpaduan INDEX dan MATCH atau VLOOKUP sekalipun

1. Satu Result dan Satu Kriteria

dan hasil yang diinginkan seperti ini

Pada cell D3 ketikkan rumus

=FILTER(B2:B4;A2:A4=D2;"")

2. Multiple Results dan Dengan Kriteria

Kemudian hasil yang diharapkan dengan kriterianya

Letakkan di cell D3
=FILTER(B2:B7;A2:A7=D2;"")

secara otomatis bisa menghasilkan beberapa hasil sesuai kriteria secara otomnatis tanpa copy satu per satu ke bawah.

3. Menampilkan Semua Kolom Sesuai Kriteria

Data seperti ini

Kemudian hasil yang diharapkan seperti ini

Letakkan rumus ini di cell H2 otomatis akan menghasilkan hasil spt diatas

=FILTER(A2:E11;B2:B11=H1)

4. Contoh lain dengan fungsi FILTER

Dengan menggunakan data sebelumnya tetapi hasil yang diinginkan berbeda jadi seperti ini

 

Ketikkan rumus di cell H4

=FILTER(B2:E11;(B2:B11=H1)+(B2:B11=H2))

Thnks guys

Menghilangkan Angka Nol dengan Custom Format

Kasusnya seperti ini ada beberapa angka nol yg ingin dihilangkan dengan custom format pada excel 

Langkahnya:

1. Blok dulu kolom yg warna kuning 

2. kemudian klik kanan lalu pilih Format Cells 

    

kemudian muncul menu Format Cells 

Pilih yang Custom

Kemudian input di bagian Type   0;-0;@ atau 0;-0;""

dan hasilnya

See u and take care guys

MENGHITUNG HURUF VOKAL DAN KONSONAN DALAM SEBUAH KATA

 Hello guys senang ketemu lagi kali kasusnya tidak berat2x amat ya menghitung jumlah huruf vokal dan konsonan dalam sebuah kata.

Kasus A (1 Kata)

Untuk menghitung vokal:

=SUMPRODUCT(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);{"a";"e";"i";"o";"u"};"")))

Untuk menghitung konsonan:

=LEN(A2)-SUMPRODUCT(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2);{"a";"e";"i";"o";"u"};"" )))

Kasus B (Multiple Text)

Untuk menghitung vokal:

=SUMPRODUCT(LEN(SUBSTITUTE(A2;" ";""))-LEN(SUBSTITUTE(LOWER(SUBSTITUTE(A2;" ";""));{"a";"e";"i";"o";"u"};"")))

Untuk menghitung konsonan:

=LEN(SUBSTITUTE(A2;" ";""))-SUMPRODUCT(LEN(SUBSTITUTE(A2;" ";""))-LEN(SUBSTITUTE(LOWER(SUBSTITUTE(A2;" ";""));{"a";"e";"i";"o";"u"};"" )))

Sekian

Rizky B. Hendrawan

MENGHITUNG ANGKA DALAM SATU CELL

 Selamat pagi semuanya pada kesempatan kali ini saya share rumus untuk menghitung angka dalam satu cell, contoh kasusnya:

Jadi kasusnya menjumlahkan semua angka dalam satu cell

Rumusnya:

=SUM(IFERROR(MID(A1;ROW(INDIRECT("1:"&LEN(A1)));1)*1;0))

atau

=SUM(IFERROR(1*MID(A1;ROW($1:$99);1);))

ini rumus array ya jadi harus tekan tombol CTRL + SHIFT + ENTER bersamaan

take care guys

Cara Mengetahui Tahun Kabisat (Leap Year)

 Pagi readers jumpa lagi artikel baru lagi di tahun 2021 tentang bagaimana mengetahui bahwa sebuah tahun adalah tahun kabisat atau bukan.

Pengertian Tahun kabisat adalah tahun yang memiliki jumlah hari yang lebih banyak daripada tahun biasa dan terjadi tiap empat tahun sekali. Jika tahun biasa jumlah hari 365 maka pada tahun kabisat terdapat 366 hari dalam setahun.

Contoh kasus

Misalnya anda punya tahun di cell B1 dan aplikasi rumusnya ada beberapa contoh di bawah ini:

1. =IF(DATE(B1+1;1;1)-DATE(B1;1;1)=366;"Tahun Kabisat";"Bukan Tahun Kabisat")

2. =IF(DAY(EOMONTH(DATE(B1;2;1);0))=29;"Tahun Kabisat";"Bukan Tahun Kabisat")

3. =IF(((MOD(B1;4)=0)*((MOD(B1;100)<>0)+(MOD(B1;400)=0))=1);"Tahun Kabisat";"Bukan Tahun Kabisat")

Regards

Rizky

Memisahkan teks dan Angka

 Senang ketemu lagi tidak menulis artikel lagi di tahun 2020 dan 2021 karena sibuk pekerjaan, kesempatan ini saya akan memberi kasus tentang memisahkan teks dan angka, kasusnya dapat dilihat di bawah ini

Kasusnya seperti diatas, untuk rumusnya:

A. Untuk Mengambil Angka dari kasus diatas, letakan di cell E3 kemudian kopas kebawah:

1. =LOOKUP(9E+99+307;--MID(B3;MIN(FIND({1;2;3;4;5;6;7;8;9;0};B3&1234567890));ROW(INDIRECT("1:"&LEN(B3)))))         

 2. =LOOKUP(20^20;1*MID(B3;MIN(SEARCH({1;2;3;4;5;6;7;8;9;0};B3&1234567890));ROW(INDIRECT("1:"&LEN(B3)))))

B. Untuk Mengambil Teks dari kasus diatas, letakkan di cell D3 kemudian kopas ke bawah:

=TRIM(SUBSTITUTE($B3;$E3;""))

Selamat malam semua

Penjumlahan dan Menghitung Dengan OR Criteria

A. MENJUMLAHKAN MULTI KRITERIA
Assalamualaikum sudah lama sekali saya tidak memberikan artikel karena kesibukan pekerjaan mohon maafkan saya. Pada kesempatan yang baik di Bulan Ramadhan ini saya akan share pengetahuan saya dalam hal penjumlahan/menghitung dengan multi kriteria dalam satu kolom. Dulu masih belajar rumus excel saya cukup kesulitan dengan kasus ini silahkan lihat tabel kasusnya dibawah ini:

Kemudian kriterianya sebagai berikut, menjumlahkan semua sales dari 3 orang ini:

Dahulu saya pikir rumusnya seperti ini:
=SUMIFS(B2:B12;A2:A12;D2;A2:A12;D3;A2:A12;D4)

Dan apa hasilnya? Ya hasilnya akan "NOL", sebetulnya penggunaan fungsi SUMIFS memang cocok untuk multiple criteria tetapi tidak beberapa kriteria dalam satu kolom karena akan menghasilkan error.

Perhatikan gambar di bawah ini:

Cobalah blok bagian ini dan akan menghasilkan gambar di bawah ini setelah kita menekan tombol F9

Pada bagian yang saya beri nomor di bawah ini menggunakan 3 kriteria tetapi dalam 1 kolom

Dimana 2 kriteria atau lebih dilakukan pada kolom yang sama dan akan menghasilkan error.


Untuk mengatasinya perlu ada modifikasi rumus? Ada beberapa metode rumus:
1. =SUM(SUMIF(A2:A12;{"Joko";"Santi";"Dewi"};B2:B12))

2. =SUM(SUMIF(A2:A12;D2:D4;B2:B12)) --> Rumus array

3. =SUMIF(A2:A12;D2;B2:B12)+SUMIF(A2:A12;D3;B2:B12)+SUMIF(A2:A12;D4;B2:B12)


B. MENGHITUNG MULTI KRITERIA
Sama halnya dengan menghitung, langsung ke tkp

Dan kriterianya seperti ini

Tabel datanya sama ya dengan yang kasus menjumlahkan tadi bedanya yang ini hanya menghitung berapa penjualannya dari 3 orang tadi.
Kita tidak bisa menggunakan rumus seperti ini

Hasilnya akan nol.

Dapat diatasi dengan 3 metode rumus
1. =SUM(COUNTIF(A2:A12;{"Joko";"Santi";"Dewi"}))

2. =SUM(COUNTIFS(A2:A12;D2:D4)) --> Rumus Array

3. =COUNTIF(A2:A12;D2)+COUNTIF(A2:A12;D3)+COUNTIF(A2:A12;D4)

UNDUH FILE LATIHAN